main.d

// D-WebUI - Serve a Folder Example

import std.file : thisExePath;
import std.format : format;
import std.path : dirName;
import std.stdio : writeln;
import std.string : representation;
import webui;

// Two files are served from D instead of from disk, so embed them.
enum testTxt = import("test.txt");
enum dynamicTxt = import("dynamic.txt");

Window mainWindow;
Window secondWindow;
int count;

void main()
{
    // Create new windows
    mainWindow = newWindow(1);
    secondWindow = newWindow(2);

    // Bind HTML element IDs with D callables
    mainWindow.bind("SwitchToSecondPage", (Event* e) { e.window.show("second.html"); });
    mainWindow.bind("OpenNewWindow", () { secondWindow.show("second.html"); });
    mainWindow.bind("Exit", () { exit(); });
    secondWindow.bind("Exit", () { exit(); });

    // An empty element name binds every event of the window
    mainWindow.bind("", &events);

    // Set the runtime used for the served `.js` and `.ts` files
    mainWindow.setRuntime(Runtime.deno);

    // Serve a couple of paths from D instead of from disk
    mainWindow.setFileHandler(&filesHandler);

    mainWindow.setSize(800, 800);
    mainWindow.setPosition(200, 200);

    // Serve the folder holding this executable, so the example works no matter
    // which directory it was started from.
    const root = dirName(thisExePath);
    mainWindow.setRootFolder(root);
    secondWindow.setRootFolder(root);

    // Show the window
    mainWindow.show("index.html");

    // Wait until all windows get closed
    wait();

    // Free all memory resources (optional)
    clean();
}

void events(Event* e)
{
    // This function gets called on every event of the window.
    switch (e.eventType)
    {
    case EventType.connected:
        writeln("Connected.");
        break;

    case EventType.disconnected:
        writeln("Disconnected.");
        break;

    case EventType.mouseClick:
        writeln("Click.");
        break;

    case EventType.navigation:
        {
            // Because this window binds "", WebUI blocks every `href` click and
            // sends it here instead, so links can be handled as needed.
            auto url = e.getString();
            writeln("Starting navigation to: ", url);
            e.window.navigate(url);
            break;
        }

    default:
        break;
    }
}

const(ubyte)[] filesHandler(string filename)
{
    writeln("File: ", filename);

    // A static file served straight from the binary.
    if (filename == "/test.txt")
        return testTxt.representation;

    // A file generated on every request. The handler returns the full HTTP
    // response, header included.
    if (filename == "/dynamic.html")
    {
        count++;
        auto page = format(dynamicTxt, count);
        return format("HTTP/1.1 200 OK\r\nContent-Type: text/html\r\nContent-Length: %d\r\n\r\n%s",
            page.length, page).representation;
    }

    // Anything else: let WebUI serve the file from the root folder.
    return null;
}