build: Compile tests for JDK 21 and fix buildSrc JVM target

Author: markushi

build.gradle.kts

@@ -116,23 +116,24 @@ allprojects {
 subprojects {
     apply { plugin("io.sentry.spotless") }
 
-    // Mockito 5 and mockito-kotlin 5+ are built for Java 11. Test code is never published, so it
-    // compiles for at least Java 11 while the published code keeps its own target. Runs in
-    // afterEvaluate, as most modules pin the JVM target of all their compile tasks.
-    afterEvaluate {
-        tasks.withType<JavaCompile>().matching { it.name.contains("Test") }.configureEach {
-            if (JavaVersion.toVersion(targetCompatibility) < JavaVersion.VERSION_11) {
-                sourceCompatibility = JavaVersion.VERSION_11.toString()
-                targetCompatibility = JavaVersion.VERSION_11.toString()
-            }
-        }
-        tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile>().matching { it.name.contains("Test") }.configureEach {
-            if (compilerOptions.jvmTarget.get() < org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_11) {
-                compilerOptions.jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_11)
+    // Mockito 5 and mockito-kotlin 5+ are built for Java 11, so test code (never published) can't
+    // share the Java 8 target of the published code; it compiles for the build JDK instead.
+    // Registered once each plugin is applied, so this afterEvaluate runs after the plugins and the
+    // module have pinned the JVM target of all compile tasks.
+    listOf("java", "com.android.library", "com.android.application").forEach { pluginId ->
+        plugins.withId(pluginId) {
+            afterEvaluate {
+                val isTestTask = { task: Task -> task.name.contains("Test") && !task.name.contains("AndroidTest") }
+                tasks.withType<JavaCompile>().matching(isTestTask).configureEach {
+                    sourceCompatibility = JavaVersion.VERSION_21.toString()
+                    targetCompatibility = JavaVersion.VERSION_21.toString()
+                }
+                tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile>().matching(isTestTask).configureEach {
+                    compilerOptions.jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_21)
+                }
             }
         }
     }
-
     listOf("com.android.library", "com.android.application").forEach { pluginId ->
         plugins.withId(pluginId) {
             // Robolectric's SDK 37 sandbox (the default, as targetSdk is 37) reflectively writes

buildSrc/build.gradle.kts

@@ -1,13 +1,7 @@
-import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
-
 plugins {
     `kotlin-dsl`
 }
 
 repositories {
     mavenCentral()
 }
-
-tasks.withType<KotlinCompile>().configureEach {
-    compilerOptions.jvmTarget = org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_17
-}

sentry-apollo/build.gradle.kts

@@ -45,6 +45,8 @@ tasks.withType<JavaCompile>().configureEach {
   options.errorprone {
     check("NullAway", net.ltgt.gradle.errorprone.CheckSeverity.ERROR)
     option("NullAway:AnnotatedPackages", "io.sentry")
+    // Generated by the Apollo plugin and marked "DO NOT MODIFY".
+    excludedPaths.set(".*/LaunchDetailsQuery.java")
   }
 }
 

sentry-system-test-support/build.gradle.kts

@@ -7,9 +7,10 @@ plugins {
   id("com.apollographql.apollo") version "4.1.1"
 }
 
+// Not published. Mockito 5 and mockito-kotlin 5+ are built for Java 11.
 configure<JavaPluginExtension> {
-  sourceCompatibility = JavaVersion.VERSION_1_8
-  targetCompatibility = JavaVersion.VERSION_1_8
+  sourceCompatibility = JavaVersion.VERSION_11
+  targetCompatibility = JavaVersion.VERSION_11
 }
 
 tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile>().configureEach {

sentry-test-support/build.gradle.kts

@@ -6,9 +6,10 @@ plugins {
   alias(libs.plugins.gradle.versions)
 }
 
+// Not published. Mockito 5 and mockito-kotlin 5+ are built for Java 11.
 configure<JavaPluginExtension> {
-  sourceCompatibility = JavaVersion.VERSION_1_8
-  targetCompatibility = JavaVersion.VERSION_1_8
+  sourceCompatibility = JavaVersion.VERSION_11
+  targetCompatibility = JavaVersion.VERSION_11
 }
 
 tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile>().configureEach {