cherrypic-server/build.gradle at develop · cherrypic-proj/cherrypic-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.3'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'com.diffplug.spotless' version '7.0.4'
    id "org.sonarqube" version '6.2.0.5505'
}

bootJar {
    enabled = false
}

repositories {
    mavenCentral()
}

sonarqube {
    properties {
        property 'sonar.projectKey', 'cherrypic-server'
        property 'sonar.organization', 'cherrypic'
        property 'sonar.host.url', 'https://sonarcloud.io'
        property 'sonar.sources', 'src'
        property 'sonar.language', 'java'
        property 'sonar.sourceEncoding', 'UTF-8'
        property 'sonar.test.inclusions', '**/*Test.java'
        property 'sonar.exclusions', '**/test/**, **/Q*.java, **/*Doc*.java, **/resources/**, **/*Application*.java, **/*Config*.java,' +
                '**/*Dto*.java, **/*Request*.java, **/*Response*.java, **/*Exception*.java, **/*ErrorCode*.java, **/*Validator*.java,' +
                '**/*FcmService*.java, **/EventImage.java, **/Notification.java, **/Favorites.java ,**/ImageEventListener.java,' +
                '**/TempAlbum.java, **/TempAlbumImage.java, **/TempAlbumType.java, **/TempAlbumType.java, **/FileExtension.java,' +
                '**/RefundTask.java, **/RefundTaskStatus.java, cherrypic-batch/**, **/StorageUnitConverter.java, **/ImageRepositoryImpl.java' +
                '**/AlbumParticipationHistory.java, **/ParticipationAction.java'
        property 'sonar.java.coveragePlugin', 'jacoco'
    }
}

subprojects {
    group = 'org.cherrypic'
    version = '0.0.1-SNAPSHOT'
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21

    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'jacoco'
    apply plugin: 'org.sonarqube'

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    jacocoTestReport {
        dependsOn test
        reports {
            html.required.set(true)
            xml.required.set(true)
            csv.required.set(false)
            xml.destination file("${buildDir}/reports/jacoco.xml")
        }

        def QDomains = []

        for (qPattern in '**/QA'..'**/QZ') {
            QDomains.add(qPattern + '*')
        }

        afterEvaluate {
            classDirectories.setFrom(
                    files(classDirectories.files.collect {
                        fileTree(dir: it,
                                excludes: [
                                        "**/*Application*",
                                        "**/*Config*",
                                        "**/*Dto*",
                                        "**/*Request*",
                                        "**/*Response*",
                                        "**/*Interceptor*",
                                        "**/*Exception*"
                                ] + QDomains)
                    })
            )
        }
    }

    sonarqube {
        properties {
            property 'sonar.java.binaries', "${buildDir}/classes"
            property 'sonar.coverage.jacoco.xmlReportPaths', "${buildDir}/reports/jacoco.xml"
        }
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        implementation 'org.springframework.boot:spring-boot-starter'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

        // lombok
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
    }

    test {
        useJUnitPlatform()
        finalizedBy jacocoTestReport
    }
}

spotless {
    java {
        target("**/*.java")
        googleJavaFormat().aosp()
        importOrder()
        removeUnusedImports()
        trimTrailingWhitespace()
        endWithNewline()
    }
}

tasks.register('updateGitHooks', Copy) {
    from './scripts/pre-commit'
    into './.git/hooks'
}

tasks.register('makeGitHooksExecutable', Exec) {
    commandLine 'chmod', '+x', './.git/hooks/pre-commit'
    dependsOn updateGitHooks
}

compileJava.dependsOn makeGitHooksExecutable