Pattern to auto-load remote justfiles

[spwoodcock]

I love the remote justfiles idea.
Not for everything, of course - many recipes belong in a specific repo - but I use them to add recipes to install nerdctl, build helm charts, etc (things that don't change and aren't repo specific).

Anyway, the problem with the suggested approach:

import? 'foo.just'

fetch:
  curl https://raw.githubusercontent.com/casey/just/master/justfile > foo.just

is that the user then has to:

# two steps. running `just foo command` without the fetch fails
just foo fetch
just foo command

To make this a bit more seamless, I wanted the justfile to auto-download when the remote commands are invoked.
In addition, I didn't want to have to maintain a module in the downstream repo that is a placeholder for the remote module.

How I'm using remote justfiles

The remote justfile, stored in a git repo:

foo.just

_self := justfile()

# List available recipes
[private]
default:
  @just --justfile {{_self}} --list

[no-cd]
mycommand:
  @printf 'Do something'

The local repo justfile:

Justfile

mod extra 'tasks/extra'

# List available commands
[private]
default:
  just help

# List available commands
help:
  just --justfile {{justfile()}} --list

# Foo module from https://github.com/myuser/justfiles
foo *args:
    @curl -sS https://raw.githubusercontent.com/myuser/justfiles/main/foo.just \
      -o {{justfile_directory()}}/tasks/foo.just;
    @just --justfile {{justfile_directory()}}/tasks/foo.just {{args}}

Now I can:

1. Run just and view all top level modules.
2. Run just foo mycommand immediately, and the remote file downloads and executes.
3. Run just foo to view the available subcommands.

Note that the ordering really matters here:

• First import your additional local modules.
• Then have your default and optional help command.
• Next, add your additional remote modules.
• Then add your top level recipes as needed.

Caveats:

• I decided to track the main branch, so all repos can be updated by updating the remote justfile (as I mentioned, bad idea with things that have potential to break, but fine for very consistent things that don't change much, and aren't repo specific).
• I also didn't add a check for the file foo.just before doing the curl command. This means curl runs every time to replace the file - a good tradeoff for me, as it makes sure the commands are up to date.